\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\* Minimum Acceptable Diet - Sample Syntax v05.11.2015 \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\*For calcuation of proportion of children aged 6-23 months who meet requirements for a minimum acceptable diet.

\*Syntax provided here is a SAMPLE ONLY. Should be modified at CO level where needed to adapt to the local context and align with

in-country data collection tools and platforms.

\*The Minimum Acceptable Diet (MAD) indicator was designed to measure the proportion of children who receive a minimum acceptable diet.

\*The MAD indicator is made up of two separate indicators: dietary diversity and meal frequency, and takes into account

the child's age and whether he/she is breastfed to determine whether the MAD threshold for diet acceptability has been reached.

\*The methodology is based on the guidance document: "Indicators for assessing infant and young child feeding practices part 2: measurement"

from the World Health Organization. Dept. of Child and Adolescent Health and Development, 2010.

\*Syntax developed by WFP Nutrition HQ with assistance from South Sudan CO and based on "MICS5 NU-08 v02 - 2014-03-05" syntax provided

by Unicef at http://www.childinfo.org/mics5\_processing.html .

\*Variable names are based on IYCF survey module, which can be found at this link:

http://whqlibdoc.who.int/publications/2010/9789241599290\_eng.pdf?ua=1 .

\*Syntax edited Nov 2015 to reflect revision to Nutrition M&E guidance on the allocation of SNFs to the Flesh Food category (previously counted under Grains, Roots, and Tubers) .

\* List of foods and IYCF question number (=variable name)

IYCF12A = Porridge, bread, rice, noodles, or other foods made from grains

IYCF12B = Pumpkin, carrots, squash, or sweet potatoes that are yellow or orange inside

IYCF12C = White potatoes, white yams, manioc, cassava, or any other foods made from roots

IYCF12D = Any dark green leafy vegetables

IYCF12E = Ripe mangoes, ripe papayas, or (insert other local vitamin A-rich fruits)

IYCF12F = Any other fruits or vegetables

IYCF12G = Liver, kidney, heart, or other organ meats

IYCF12H = Any meat, such as beef, pork, lamb, goat, chicken, or duck

IYCF12I = Eggs

IYCF12J = Fresh or dried fish, shellfish, or seafood

IYCF12K = Any foods made from beans, peas, lentils, nuts, or seeds

IYCF12L = Cheese, yogurt, or other milk products

IYCF12Q = Foods made with red palm oil, red palm nut, or red palm nut pulp sauce

Addition:

WFPSNF1 = WFP Specialized Nutritious Product - Fortified Solid, Semi-solid, or Soft Foods for Infants/Children

WFPSNF2 = WFP Specialized Nutritious Product - Micronutrient Powders

WFPSNF3 = WFP Specialized Nutritious Product - LNS.

\*Any other SNF should be specified with a new variable.

\* The 7 food groups:

1) Grains, roots, and tubers: IYCF10G, IYCF12A, and IYCF12C

2) Legumes and nuts: IYCF12K

3) Dairy products: IYCF10B, IYCF10C, IYCF10F, IYCF12L (note: dairy excluded as a food group for non-breastfed children as milk feeds are counted separately)

4) Flesh foods: IYCF12G, IYCF12H, IYCF12J, WFPSNF1, WFPSNF2, and WFPSNF3

5) Eggs: IYCF12I

6) Vitamin A rich fruits and vegetables: IYCF12B, IYCF12D, IYCF12E and IYCF12Q

7) Other fruits and vegetables: IYCF12F.

\*Addititional variables:

IYCF7 = Currently breastfed ( 0=NO, 1=YES )

IYCF10B = Infant formula

IYCF10C = Milk (fresh, tinned, powdered)

IYCF10F = Yogurt

IYCF10G = Porridge

IYCF11B = Number of times child consumed infant formula

IYCF11C = Number of times child consumed milk

IYCF11F = Number of times child consumed yogurt

IYCF14 = Number of times child ate solid, semi-solid, or soft foods other than liquids yesterday during the day or at night

\* Minimum dietary diversity (for both breastfed and non-breastfed children):

Children who received food from at least 4 of the food groups listed above.

\* Minimum meal frequency:

a) If currently breastfed:

i) Age 6-8 months: Solid, semi-solid, or soft foods at least two times (IYCF14>=2)

ii) Age 9-23 months: Solid, semi-solid, or soft foods at least three times (IYCF14>=3)

b) If not currently breastfed:

Must receive at least 2 milk feeds: (IYCF11B + IYCF11C + IYCF11F >= 2)

Must consume solid, semi-solid, or soft foods (of which at least 2 are milk feeds), at least 4 times: (IYCF11B + IYCF11C + IYCF11F + IYCF14 >= 4) .

\* Minimum acceptable diet:

a) Currently breastfed:

Children who received the minimum dietary diversity and the minimum meal frequency as per age groups defined above

b) Currently not breastfed:

Children who received the minimum meal frequency, at least 2 milk feeds, and the minimum dietary diversity (calculated based

on 6 food groups only - dairy excluded).

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.

get file = "filename.sav".

\*Recode missing values to zero.

recode IYCF11B IYCF11C IYCF11F (sysmis=0).

variable labels IYCF7 "Breastfeeding status".

value labels IYCF7

0 "Child not breastfed"

1 "Child breastfed".

SELECT IF (ageinmonths >=6 AND ageinmonths <24).

\*Minimum dietary diversity - create variables for each food group.

compute grainsRootsTubers = any(1, IYCF10G, IYCF12A, IYCF12C) .

IF MISSING(grainsRootsTubers) grainsRootsTubers=0.

compute legumesNuts = any(1, IYCF12K) .

IF MISSING(legumesNuts) legumesNuts=0.

do if (IYCF7 = 1) .

+ compute dairyProducts = any(1, IYCF10B, IYCF10C, IYCF10F, IYCF12L) .

end if.

IF (IYCF7=0 or MISSING(dairyProducts)) dairyProducts=0.

compute fleshFoods = any(1, IYCF12G, IYCF12H, IYCF12J, WFPSNF1,WFPSNF2, WFPSNF3) .

IF MISSING(fleshFoods) fleshFoods=0.

compute eggs = any(1, IYCF12I) .

IF MISSING(eggs) eggs=0.

compute vitaminA = any(1, IYCF12B, IYCF12D, IYCF12E, IYCF12Q) .

IF MISSING(vitaminA) vitaminA=0.

compute other = any(1, IYCF12F) .

IF MISSING(other) other=0.

compute minimumDietaryDiversity = sum(grainsRootsTubers, legumesNuts, dairyProducts, fleshFoods, eggs, vitaminA, other) >= 4 .

IF MISSING(minimumDietaryDiversity) minimumDietaryDiversity=0.

variable labels minimumDietaryDiversity "Min dietary diversity".

value labels minimumDietaryDiversity

0 "Does not meet Min Diet Diversity"

1 "Meets Min Diet Diversity".

\*Minimum meal frequency for breastfed children.

do if (IYCF7 = 1) .

+ do if (ageinmonths >= 6.00 and ageinmonths <= 8.99).

+ compute minimumMealFrequency = IYCF14>=2 .

+ else .

+ compute minimumMealFrequency = IYCF14>=3 .

+ end if.

end if.

\*Minimum meal frequency for non-breastfed children (must meet requirements for milk feeds and number of meals).

do if (IYCF7 = 0) .

+ compute atLeast2Milk = (IYCF11B + IYCF11C + IYCF11F) >= 2 .

+ do if (atLeast2Milk).

+ compute minimumMealFrequency = (IYCF11B + IYCF11C + IYCF11F + IYCF14) >= 4 .

+ end if.

end if.

IF MISSING(atLeast2Milk) atLeast2Milk=0.

IF MISSING(minimumMealFrequency) minimumMealFrequency=0.

variable labels minimumMealFrequency "Minimum Meal Frequency".

value labels minimumMealFrequency

0 "Does not meet Min Meal Frequency"

1 "Meets Min Meal Frequency".

variable labels atLeast2Milk "At least 2 milk feeds".

value labels atLeast2Milk

0 "Does not meet at least 2 milk feeds"

1 "Meets at least 2 milk feeds".

\* Minimum acceptable diet for breastfed and non-breastfed children.

compute minimumAcceptableDiet = minimumDietaryDiversity & minimumMealFrequency .

variable labels minimumAcceptableDiet "Minimum Acceptable Diet".

value labels minimumAcceptableDiet

0 "Does not meet Min Acceptable Diet"

1 "Meets Min Acceptable Diet".

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*Output tables\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*.

\* Age by category.

recode ageinmonths

(6.0 thru 11.999 = 1)

(12.0 thru 17.999 = 2)

(else = 3) into ageCat.

variable labels ageCat "Age".

value labels ageCat

1 "6-11 months"

2 "12-17 months"

3 "18-23 months".

\* Table - Proportion of children meeting MAD for each age group.

CTABLES

/VLABELS VARIABLES=ageCat minimumAcceptableDiet DISPLAY=LABEL

/TABLE ageCat [C] BY minimumAcceptableDiet [C][COUNT F40.0, ROWPCT.COUNT PCT40.1]

/CATEGORIES VARIABLES=ageCat ORDER=A KEY=VALUE EMPTY=INCLUDE TOTAL=YES LABEL='Total, 6-23 mos' POSITION=AFTER

/CATEGORIES VARIABLES=minimumAcceptableDiet ORDER=A KEY=VALUE EMPTY=INCLUDE.

\* OPTIONAL TABLES - Proportion of children meeting MDD, MMF, and proportion breastfed for each age group.

CTABLES

/VLABELS VARIABLES=ageCat minimumDietaryDiversity DISPLAY=LABEL

/TABLE ageCat [C] BY minimumDietaryDiversity [C][COUNT F40.0, ROWPCT.COUNT PCT40.1]

/CATEGORIES VARIABLES=ageCat ORDER=A KEY=VALUE EMPTY=INCLUDE TOTAL=YES LABEL='Total, 6-23 mos' POSITION=AFTER

/CATEGORIES VARIABLES=minimumDietaryDiversity ORDER=A KEY=VALUE EMPTY=INCLUDE.

CTABLES

/VLABELS VARIABLES=ageCat minimumMealFrequency DISPLAY=LABEL

/TABLE ageCat [C] BY minimumMealFrequency [C][COUNT F40.0, ROWPCT.COUNT PCT40.1]

/CATEGORIES VARIABLES=ageCat ORDER=A KEY=VALUE EMPTY=INCLUDE TOTAL=YES LABEL='Total, 6-23 mos' POSITION=AFTER

/CATEGORIES VARIABLES=minimumMealFrequency ORDER=A KEY=VALUE EMPTY=INCLUDE.

CTABLES

/VLABELS VARIABLES=ageCat IYCF7 DISPLAY=LABEL

/TABLE ageCat [C] BY IYCF7 [C][COUNT F40.0, ROWPCT.COUNT PCT40.1]

/CATEGORIES VARIABLES=ageCat ORDER=A KEY=VALUE EMPTY=INCLUDE TOTAL=YES LABEL='Total, 6-23 mos' POSITION=AFTER

/CATEGORIES VARIABLES=IYCF7 ORDER=A KEY=VALUE EMPTY=INCLUDE.